1 概述

1. 目的：'快速定位程序異常'

2. 包處理的核心思想：'自治事務' -- 自治事務的 "提交、回滾" 與主事務之間互不影響

3. 錯誤異常記錄邏輯大體一致，此處記錄，方便需要使用時復制、粘貼

4. 驗證思路：通過執(zhí)行報錯的過程，觀察 '程序執(zhí)行結果' 和 '日志表' 數據插入情況

2 效果演示

程序執(zhí)行截圖：

日志表查詢截圖：

3 源碼

說明：
1. 測試中，共有 2 個用戶 -- 模擬實際開發(fā)場景
  (1) odsdata: 存放業(yè)務數據
  (2) odscde : 執(zhí)行具體操作
  -- 為了方便測試，也可以去掉所有 '屬主 owner'

3.1 錯誤日志表

CREATE TABLE odsdata.ods_program_error_log (
 error_log_id    VARCHAR2(10) NOT NULL, -- CONSTRAINT pk_opel_error_log_id PRIMARY KEY(error_log_id)
 owner        VARCHAR2(30),
 package_name    VARCHAR2(30),
 procedure_name   VARCHAR2(30),
 error_comment    VARCHAR2(1000),
 error_backtrace   VARCHAR2(400),
 error_stack     VARCHAR2(4000),
 call_stack     VARCHAR2(4000),
 error_date     DATE NOT NULL,
 oracle_execute_user VARCHAR2(50),
 um_id        VARCHAR2(50)
);

COMMENT ON TABLE odsdata.ods_program_error_log IS '程序錯誤日志表';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_log_id IS '錯誤日志id';
COMMENT ON COLUMN odsdata.ods_program_error_log.owner IS '屬主';
COMMENT ON COLUMN odsdata.ods_program_error_log.package_name IS '包名';
COMMENT ON COLUMN odsdata.ods_program_error_log.procedure_name IS '過程名';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_comment IS '錯誤備注';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_backtrace IS '錯誤跟蹤';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_stack IS '錯誤堆棧';
COMMENT ON COLUMN odsdata.ods_program_error_log.call_stack IS '調用堆棧';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_date IS '錯誤時間';
COMMENT ON COLUMN odsdata.ods_program_error_log.oracle_execute_user IS 'oracle執(zhí)行用戶';
COMMENT ON COLUMN odsdata.ods_program_error_log.um_id IS '操作人員um賬號';

GRANT SELECT, INSERT, UPDATE ON odsdata.ods_program_error_log TO odscde;

3.2 異常處理包

擴展：Oracle 序列詳解（sequence）

package：

CREATE OR REPLACE PACKAGE odscde.pkg_ods_error_handle IS
 --*************************************************
 --功能說明: 錯誤日志
 --參數說明: i_procedure_name 程序名
 --     i_error_comment  錯誤備注（手工添加的）
 --調用函數:
 --修改記錄： create by YoYo 2020-12-17
 --*************************************************
 PROCEDURE exception_handle(i_procedure_name IN VARCHAR2,
               i_error_comment IN VARCHAR2);
END pkg_ods_error_handle;

package body：

CREATE OR REPLACE PACKAGE BODY odscde.pkg_ods_error_handle IS
 --*************************************************
 --功能說明: 錯誤日志
 --參數說明: i_procedure_name 程序名
 --     i_error_comment  錯誤備注（手工添加的）
 --調用函數:
 --修改記錄： create by YoYo 2020-12-17
 --*************************************************
 PROCEDURE exception_handle(i_procedure_name IN VARCHAR2,
               i_error_comment IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION; -- !!! 自治事務
  v_log_info odsdata.ods_program_error_log%ROWTYPE;
 BEGIN
  v_log_info.error_log_id    := '1'; -- 異常錯誤id（一般是 "獲取序列號"，此處僅演示）
  v_log_info.procedure_name   := i_procedure_name; -- 程序名
  v_log_info.error_comment    := i_error_comment;
  v_log_info.oracle_execute_user := sys_context('USERENV', 'SESSION_USER'); -- oracle執(zhí)行用戶
  v_log_info.um_id        := nvl(sys_context('USERENV', 'OS_USER'),
                     USER); -- 操作人員um賬號
  v_log_info.error_backtrace   := dbms_utility.format_error_backtrace; -- 錯誤跟蹤
  v_log_info.error_stack     := dbms_utility.format_error_stack; -- 錯誤堆棧
  v_log_info.call_stack     := dbms_utility.format_call_stack; -- 調用堆棧
  v_log_info.error_date     := SYSDATE;
 
  -- 可選列
  ---- 包屬主
  v_log_info.owner := substr(v_log_info.error_backtrace,
                instr(v_log_info.error_backtrace, '"', 1) + 1,
                (instr(v_log_info.error_backtrace, '.', 1) -
                instr(v_log_info.error_backtrace, '"', 1) - 1));
  ---- 包名
  v_log_info.package_name := substr(v_log_info.error_backtrace,
                   instr(v_log_info.error_backtrace,
                      '.',
                      1) + 1,
                   (instr(v_log_info.error_backtrace,
                       '"',
                       1,
                       2) - instr(v_log_info.error_backtrace,
                             '.',
                             1) - 1));
 
  -- 插入數據
  INSERT INTO odsdata.ods_program_error_log
   (error_log_id,
    owner,
    package_name,
    procedure_name,
    error_comment,
    error_backtrace,
    error_stack,
    call_stack,
    error_date,
    oracle_execute_user,
    um_id)
  VALUES
   (v_log_info.error_log_id,
    v_log_info.owner,
    v_log_info.package_name,
    v_log_info.procedure_name,
    v_log_info.error_comment,
    v_log_info.error_backtrace,
    v_log_info.error_stack,
    v_log_info.call_stack,
    v_log_info.error_date,
    v_log_info.oracle_execute_user,
    v_log_info.um_id);
 
  COMMIT;
 END exception_handle;
END pkg_ods_error_handle;

3.3 測試程序

演示報錯：違反唯一性約束

stu_info：

CREATE TABLE odsdata.stu_info (
 sno  NUMBER(10) CONSTRAINT pk_si_sno PRIMARY KEY,
 sname VARCHAR2(50) NOT NULL
);

GRANT SELECT, INSERT, UPDATE ON odsdata.stu_info TO odscde;

INSERT INTO odsdata.stu_info(sno, sname) VALUES(1, '瑤瑤');
COMMIT;

package:

CREATE OR REPLACE PACKAGE odscde.pkg_ods_error_test AS
 PROCEDURE ods_error_test(o_flag  OUT VARCHAR2,
              o_message OUT VARCHAR2);
END pkg_ods_error_test;

package body：

CREATE OR REPLACE PACKAGE BODY odscde.pkg_ods_error_test AS
 PROCEDURE ods_error_test(o_flag  OUT VARCHAR2,
              o_message OUT VARCHAR2) IS
  i_procedure_name VARCHAR2(30) := 'ods_error_test';
 BEGIN
  INSERT INTO odsdata.stu_info (sno, sname) VALUES (1, '瑤瑤');
  COMMIT;
 
  o_flag  := 'Y';
  o_message := '執(zhí)行成功！';
 EXCEPTION
  WHEN OTHERS THEN
   o_flag  := 'N';
   o_message := '執(zhí)行失??！';
   pkg_ods_error_handle.exception_handle(i_procedure_name => i_procedure_name,
                      i_error_comment => '' -- 關鍵入參、出參
                      );
 END ods_error_test;
END pkg_ods_error_test;

到此這篇關于Oracle 錯誤日志表及異常處理包詳解附源碼的文章就介紹到這了,更多相關Oracle 錯誤日志表內容請搜索腳本之家以前的文章或繼續(xù)瀏覽下面的相關文章希望大家以后多多支持腳本之家！

您可能感興趣的文章: